#!/usr/bin/perl -w
use strict;
use IO::File;

package SerialDecode;
use strict;
sub new {
    my ($class)=@_;
    return bless { state=>0, byte=>0 }, $class;
}
sub decode {
    my ($self, $bits)= @_;
    for (my $ofs= 0; $ofs<length($bits) ; $ofs++) {
        my $bit= substr($bits, $ofs, 1);
        if ($self->{state}==0) {
            # looking for startbit
            if ($bit==0) {
                $self->{state}= 1;
            }
        }
        elsif ($self->{state}>=1 && $self->{state}<=8) {
            # collecting 8 bits
            $self->{byte}>>=1;
            $self->{byte} |= $bit<<7;
            $self->{state}++;
        }
        elsif ($self->{state}==9) {
            printf(" %02x", $self->{byte});
            if ($bit==1) {
                # found stopbit
                $self->{state}= 0;
            }
            else {
                print "?";
                # missing stopbit
                $self->{state}= 1;
            }
        }
    }
}

package main;
my @bitreverse= (0x00, 0x80, 0x40, 0xc0, 0x20, 0xa0, 0x60, 0xe0, 0x10, 0x90, 0x50, 0xd0, 0x30, 0xb0, 0x70, 0xf0, 0x08, 0x88, 0x48, 0xc8, 0x28, 0xa8, 0x68, 0xe8, 0x18, 0x98, 0x58, 0xd8, 0x38, 0xb8, 0x78, 0xf8, 0x04, 0x84, 0x44, 0xc4, 0x24, 0xa4, 0x64, 0xe4, 0x14, 0x94, 0x54, 0xd4, 0x34, 0xb4, 0x74, 0xf4, 0x0c, 0x8c, 0x4c, 0xcc, 0x2c, 0xac, 0x6c, 0xec, 0x1c, 0x9c, 0x5c, 0xdc, 0x3c, 0xbc, 0x7c, 0xfc, 0x02, 0x82, 0x42, 0xc2, 0x22, 0xa2, 0x62, 0xe2, 0x12, 0x92, 0x52, 0xd2, 0x32, 0xb2, 0x72, 0xf2, 0x0a, 0x8a, 0x4a, 0xca, 0x2a, 0xaa, 0x6a, 0xea, 0x1a, 0x9a, 0x5a, 0xda, 0x3a, 0xba, 0x7a, 0xfa, 0x06, 0x86, 0x46, 0xc6, 0x26, 0xa6, 0x66, 0xe6, 0x16, 0x96, 0x56, 0xd6, 0x36, 0xb6, 0x76, 0xf6, 0x0e, 0x8e, 0x4e, 0xce, 0x2e, 0xae, 0x6e, 0xee, 0x1e, 0x9e, 0x5e, 0xde, 0x3e, 0xbe, 0x7e, 0xfe, 0x01, 0x81, 0x41, 0xc1, 0x21, 0xa1, 0x61, 0xe1, 0x11, 0x91, 0x51, 0xd1, 0x31, 0xb1, 0x71, 0xf1, 0x09, 0x89, 0x49, 0xc9, 0x29, 0xa9, 0x69, 0xe9, 0x19, 0x99, 0x59, 0xd9, 0x39, 0xb9, 0x79, 0xf9, 0x05, 0x85, 0x45, 0xc5, 0x25, 0xa5, 0x65, 0xe5, 0x15, 0x95, 0x55, 0xd5, 0x35, 0xb5, 0x75, 0xf5, 0x0d, 0x8d, 0x4d, 0xcd, 0x2d, 0xad, 0x6d, 0xed, 0x1d, 0x9d, 0x5d, 0xdd, 0x3d, 0xbd, 0x7d, 0xfd, 0x03, 0x83, 0x43, 0xc3, 0x23, 0xa3, 0x63, 0xe3, 0x13, 0x93, 0x53, 0xd3, 0x33, 0xb3, 0x73, 0xf3, 0x0b, 0x8b, 0x4b, 0xcb, 0x2b, 0xab, 0x6b, 0xeb, 0x1b, 0x9b, 0x5b, 0xdb, 0x3b, 0xbb, 0x7b, 0xfb, 0x07, 0x87, 0x47, 0xc7, 0x27, 0xa7, 0x67, 0xe7, 0x17, 0x97, 0x57, 0xd7, 0x37, 0xb7, 0x77, 0xf7, 0x0f, 0x8f, 0x4f, 0xcf, 0x2f, 0xaf, 0x6f, 0xef, 0x1f, 0x9f, 0x5f, 0xdf, 0x3f, 0xbf, 0x7f, 0xff);

my $fn= shift;
my $fh=$fn ? IO::File->new($fn, "r") : *STDIN;
if (!$fh) { die "$fn: $!\n"; }

binmode $fh;

my $v110data="";
if ($fn) {
    $fh->read($v110data, -s $fh);
}
else {
    while (!$fh->eof())
    {
        $fh->read($v110data, 0x10000, length($v110data));
    }
}
$fh->close();

my $serial= SerialDecode->new();
printf("l=%08lx\n", length($v110data));
my $ofs=0;
while ($ofs<length($v110data))
{
    my $n=index($v110data, "????", $ofs);
    if ($n==-1) {
        printf("%08lx: %s\n", $ofs, summarizedata(substr($v110data, $ofs)));
        last;
    }
    if ($ofs<$n) {
        printf("%08lx: %s\n", $ofs, summarizedata(substr($v110data, $ofs, $n-$ofs)));
    }

    $ofs= $n;

    my $framedata= substr($v110data, $ofs, 40);
    my $frame= decode_frame($framedata);

    if (!$frame) {
        printf("%08lx: %s\n", $ofs, summarizedata($framedata));
    }
    else {
        printf("%08lx: %s - ", $ofs, framestring($frame));
        $serial->decode(join("", map { sprintf("%06b", $frame->{d}[$_]) } 0..7));
        printf("\n");
    }
    $ofs = $ofs+40;
}
printf("end: %08lx\n", $ofs);
sub summarizedata {
    my $data= shift;
    $data =~ s/.+/sprintf(", %d dup(%02x)", length($&), ord($&))/egs;
    $data =~ s/^, //;
    return $data;
}
sub takeupperbits {
    my $frame= shift;
    my @bytes;
    my @bitswap= (0,2,1,3);
    for (my $i=0 ; $i<length($frame) ; $i++)
    {
        if (($i&3)==0) {
            push @bytes, 0;
        }
        #$bytes[-1] <<=2;
        #$bytes[-1] |= ord(substr($frame, $i, 1))>>6;
        $bytes[-1] >>=2;
        my $bits= $bitswap[ord(substr($frame, $i, 1))>>6]<<6;

        $bytes[-1] |= $bits;
    }
    return @bytes;
}

# see ~/docs/itu/v110.pdf   section 5.1.2.1
sub decode_frame {
    my $frame=shift;
    return undef if $frame !~ /^[\x3f\x7f\xbf\xff]{40}$/;
    my @bytes= takeupperbits($frame);

    # d = data bits D1 .. D48
    # s = S bits S1 .. S9   status bits
    # e = E bits E1 .. E7
    # x = 2 X bits   status bits
    # zero is first octet
    # one is lowest bit of next octets
    my ($d, $s, $e, $x, $zero, $one)= split_dsex(@bytes);

    return {
        d=>$d, s=>$s, e=>$e, x=>$x, zero=>$zero, one=>$one,
    };
}
sub bitreverse {
    my ($x, $n)= @_;
    if ($n<=8) {
        return $bitreverse[$x]>>(8-$n);
    }
    elsif ($n<=16) {
        return (bitreverse($x&0xff, 8)<<($n-8)) | bitreverse($x>>8, $n-8);
    }
    die "unsupported bitreverse\n";
}
sub split_dsex {
    my @d;
    my ($s, $e, $x, $zero, $one)=(0,0,0,0,0);

    $zero= $_[0];
    for (1..9) {
        $one <<= 1;
        $one |= $_[$_]>>7;
        if ($_ != 5) {
            push @d, bitreverse(($_[$_]>>1)&0x3f, 6);
        }
        $s <<= 1;
        if ($_ == 5) {
            $e = bitreverse($_[$_]&0x7f, 7);
        }
        elsif ($_ == 2 || $_ == 7) {
            $x <<= 1;
            $x |= $_[$_]&1;
        }
        else {
            $s |= $_[$_]&1;
        }
    }
    $s= bitreverse($s, 9);
    return (\@d, $s, $e, $x, $zero, $one);
}

sub framestring {
    my ($f)= @_;

    return sprintf("%d %d e:%07b s:%09b x:%02b d:%s", $f->{zero}, $f->{one}^0x1ff, $f->{e}, $f->{s}, $f->{x},
        join(" ", map { sprintf("%06b", $f->{d}[$_]) } 0..7));
}
__END__
          102   Signal ground or common return 
          102a  DTE common return 
          102b  DCE common return 
          
          103   Transmitted data 
          104   Received data 

SB = S4+S9
SA = S1,S3,S6,S8

t2i| i2t| 
SB |    | 105   Request for sending
   | X  | 106   Ready for sending 
   | SA | 107    Data set ready  
SA |    | 108/1  Connect data set to line 
SA |    | 108/2  Data terminal ready 
   | SB | 109    Data channel received line signal detector 
   | X  | 133   Ready for receiving  
          
          113   Transmitter signal element timing (DTE source) 
          114   Transmitter signal element timing (DCE source) 
          115   Receiver signal element timing (DCE source) 
          125   Calling indicator 
          140   Loopback/maintenance test 
          141   Local loopback 
          142   Test indicator