#!perl -w
use strict;
use IO::File;
use Compress::Zlib;

my $filenr=0;

my $fn= shift or die "need fn\n";
my $fh= IO::File->new($fn) or die "$fn: $!\n";
binmode $fh;

my $hdrdata= read_sisx_header($fh);
my $hdr= parse_sisx_header($hdrdata);

my $blockdata= read_sisx_block($fh);

my $sisx= parse_sisx_block($blockdata);
use Dumpvalue;
my $d= new Dumpvalue;
$d->dumpValue($sisx);

sub read_sisx_header {
    my ($fh)= @_;
    my $hdrdata;
    $fh->read($hdrdata, 20);
    return $hdrdata;
}
sub parse_sisx_header {
    my ($hdrdata)= @_;
    my %hdr;
    (
        $hdr{dw1},
        $hdr{dw2},
        $hdr{dw3},
        $hdr{dw4},
        $hdr{dw5},
    ) = unpack("VVVVV", $hdrdata);
    return \%hdr;
}
sub read_sisx_block {
    my ($fh) = @_;
    my $hdr;
    $fh->read($hdr, 4);
    my ($len)= unpack("V", $hdr);
    my $data;
    $fh->read($data, $len);
    return $hdr.$data;
}

sub parse_sisx_block {
    my ($blockdata)= @_;
    my $ofs= 0;
    my @blocks;
    while ($ofs<length($blockdata)) {
        my ($len, $type)= unpack("VV", substr($blockdata, $ofs, 8));
        printf("%08lx: block l=%08lx t=%08lx\n", $ofs, $len, $type);

        my %block;
        if ($type==0x22) {
            # file header
            my @dw;
            my $len1;
            (@dw[0..5], $len1)= unpack("V7", substr($blockdata, $ofs+8, 7*4));
            $block{dw}=\@dw;
            $block{hdrfile}= parse_sisx_block(substr($blockdata, $ofs+8*4, $len1+4));
            $len = 9*4+rounddw($len1);
            $block{dw2}= unpack("V", substr($blockdata, $ofs+$len, 4));
        }
        elsif ($type==1) {
            # compressed data
            my ($uncompressedsize, $flag)= unpack("VV", substr($blockdata, $ofs+8,8));
            $block{filedata}= uncompress(substr($blockdata, $ofs+16, $len-12));
            savefile($block{filedata});
            if (!defined $block{filedata}) {
                printf("compress failed\n");
            }
            $block{uncompressedsize}= $uncompressedsize;
            $block{flag}= $flag;
        }
        elsif ($type==0) {
            # uncompressed data
            my ($uncompressedsize, $flag)= unpack("VV", substr($blockdata, $ofs+8,8));
            $block{filedata}= substr($blockdata, $ofs+16, $len-12);
            savefile($block{filedata});
            $block{uncompressedsize}= $uncompressedsize;
            $block{flag}= $flag;
        }
        elsif ($type==2) {
            $block{data2}= parse_sisx_block(substr($blockdata, 8+$ofs, $len-4));
        }
        elsif ($type==3) {
            $block{data3}= parse_sisx_block(substr($blockdata, 8+$ofs, $len-4));
        }
        elsif ($type==0x1f) {
            $block{data1f}= parse_sisx_block(substr($blockdata, 8+$ofs, $len-4));
        }
        elsif ($type==0x20) {
            # loop
            $block{data20}= parse_sisx_block(substr($blockdata, 8+$ofs, $len-4));
        }
        else {
            printf("%08lx: unrecognized block type %08lx  .. l=%08lx\n", $ofs, $type, length($blockdata));
        }

        push @blocks, {
            ofs=>$ofs,
            block=>\%block,
        };
        $ofs += rounddw($len)+4;
    }
    return \@blocks;
}
sub rounddw {
    if ($_[0]&3) {
        return ($_[0]|3)+1;
    }
    else {
        return $_[0];
    }
}
sub savefile {
    my ($data)= @_;
    my $fn= sprintf("sisxblock-%d.nb", $filenr++);
    my $fh= IO::File->new($fn, "w") or die "$fn: $!\n";
    binmode $fh;
    $fh->print($data);
    $fh->close();
}